Supplement to:
“A Congruence Family For 2-Elongated Plane Partitions: An Application of the Localization Method,” 
Nicolas Allen Smoot
Research Institute for Symbolic Computation
(RISC), Linz

We will outline the computational method by which our initial cases may be derived from our 6 fundamental relations.  Justification is purely an algebraic computation which, aside from its tedious length, is not overly complicated.  Proof of the 6 fundamental relations is more difficult, and is based on the theory of modular functions (See our Paper).

We begin by listing the 6 fundamental relations, followed by the important modular equations that we need.  We show how to extend our U3 operator to arbitrary powers of our key modular function, x.  Following this, we compute our 6 initial relations.

In addition, we will verify the coefficient congruences that are extremely useful to our proof, and which arise from the same calculations as the fundamental relations.

We will also give some miscellaneous calculations which are not especially difficult, but tedious enough to warrant placement here rather than in the main article.

We will give the explicit cusp analysis computations needed to justify our 6 fundamental relations, along with the relation between z and x, and our modular equation for x.

Finally, we give some additional computations to demonstrate how to give lower bounds on the orders of our functions (Subscript[L, α]), together with expressions for (Subscript[L, 1]), (Subscript[L, 2]), (Subscript[L, 3]).

Fundamental Relations

We begin by listing our ten fundamental relations.

Here for

1 ≤ m ≤ 2,

U1xm = (Subscript[U, 3])(((x(τ))^m)),

and

U0xm = (Subscript[U, 3])(A(τ)×((x(τ))^m)).

For m=0 we will simply write U1 and U0.

Notice that we give U1x3 as well.  This is unnecessary, and we give it only to provide a point of reference to compare with our later computations.

U1=1;

U1x=19 x+360 (x^2)+1728 (x^3);

U1x2=10 x+1269 (x^2)+41904 (x^3)+585792 (x^4)+3732480 (x^5)+8957952 (x^6);

U0=(1/(1+9 x)) (33 x+1392 (x^2)+21120 (x^3)+138240 (x^4)+331776 (x^5));

U0x=(1/(1+9 x)) (12 x+2325 (x^2)+121080 (x^3)+2915136 (x^4)+37988352 (x^5)+277696512 (x^6)+1074954240 (x^7)+1719926784 (x^8));

U0x2=(1/(1+9 x)) (x+1213 (x^2)+176005 (x^3)+10225152 (x^4)+318757248 (x^5)+6012278784 (x^6)+72239910912 (x^7)+558546223104 (x^8)+2698565124096 (x^9)+7430083706880 (x^10)+8916100448256 (x^11));

We will give U1x3 as well.  This is unnecessary, and we give it only to provide a point of reference to compare with our later computations.

U1x3=x+873 (x^2)+93915 (x^3)+3961872 (x^4)+86173632 (x^5)+1064876544 (x^6)+7578427392 (x^7)+29023764480 (x^8)+46438023168 (x^9);

Terms of the Modular Equations

We use the modular equations from our paper in order to build recurrence formulae for arbitrary powers of x.  We list the terms of each modular equation here.  Coefficients of (x^j) will be denoted aj, while coefficients of (z^k) will be denoted bk.

a0[x3_]:=-(81 (x3^3)+18 (x3^2)+x3)

a1[x3_]:=-(1296 x3^3+279 x3^2+15 x3)

a2[x3_]:=-(5184 x3^3+1080 x3^2+57 x3)

(x^3)+(∑_(j=0)^2)aj(x(3τ))×(x^j)=0

b0[z3_]:=-(z3^3)

b1[z3_]:=1+9 z3+9 (z3^2)-16 (z3^3)

b2[z3_]:=-2-9 z3+72 (z3^2)-64 (z3^3)

b3[z3_]:=1

If z(τ)=1+9x(τ), then (z^3)+(∑_(j=0)^2)bk(z(3τ))×(x^j)=0.

Extending the U-Operator for Arbitrary Powers of x

We now begin to build our recurrence formulae.  Starting with

(Subscript[U, 3])(((x(τ))^m)),

we quickly build tables to reference the 3 consecutive relations we already know, together with the modular equation for x.

U1v={U1,U1x,U1x2};

av={a0[x],a1[x],a2[x]};

We now build our recurrence.

U1X[m_]:=
If[
0≤m≤2,
U1v[[m+1]],
If[
m≥3,
-Sum[av[[j+1]] U1X[j+m-3],{j,0,2}],
0
]
]//Simplify//Expand

As an example:

(U1X[3]//Simplify)//Expand

Notice that this agrees with the value of U1x3 that we have already given:

U1x3

Similarly for  (Subscript[U, 3])(A(τ)×((x(τ))^m)):

U0v={U0,U0x,U0x2};

U0X[m_]:=
If[
0≤m≤2,
U0v[[m+1]],
If[
m≥3,
-Sum[av[[j+1]] U0X[j+m-3],{j,0,2}],
0
]
]//Simplify//Expand

As an example:

(U0X[3]//Simplify)//Expand

Now we need recurrence formulae for

(Subscript[U, 3])((((1+9y(τ)))^m)).

Again, we build a table to reference the modular equation for x.

bv={b1[1+9 x],b2[1+9 x],b3[1+3 x]};

We now build our recurrences.

U1Z[n_]:=
If[
n≥0,
Sum[
Binomial[n,k] 9^k U1X[k],
{k,0,n}
],
-Sum[bv[[j]] ((U1Z[n+j])/(b0[1+9 x])),{j,1,3}]
]//Simplify//Expand

U0Z[n_]:=
If[
n≥0,
Sum[
Binomial[n,k] 9^k U0X[k],
{k,0,n}
],
-Sum[bv[[j]] ((U0Z[n+j])/(b0[1+9 x])),{j,1,3}]
]//Simplify//Expand

We test it.

(U1Z[-1])//Simplify//Expand

(U0Z[-2])//Simplify//Expand

We now have enough to build our general formulae for

 (Subscript[U, 3])(((x^m)/(((1+9x))^n))), 

which we will denote by U1XoZ[m,n], and

(Subscript[U, 3])(A(τ)×((x^m)/(((1+9x))^n))),

which we will denote by U0XoZ[m,n].

U1XoZ[m_,n_]:=
If[
m==0,
U1Z[-n],
(1/(9^m)) Sum[(-1)^(m-l) Binomial[m,l] U1Z[l-n],{l,0,m}]
]//Simplify//Expand

U0XoZ[m_,n_]:=
If[
m==0,
U0Z[-n],
(1/(9^m)) Sum[(-1)^(m-l) Binomial[m,l] U0Z[l-n],{l,0,m}]
]//Simplify//Expand

We test them.

(U1XoZ[0,1]//Simplify)//Expand

(U1XoZ[0,2]//Simplify)//Expand

(U0XoZ[0,1]//Simplify)//Expand

(U0XoZ[0,2]//Simplify)//Expand

We can now start examining specific cases of

(Subscript[U, 3])(((x^m)/(((1+9x))^n))) 
 
 and
 
 (Subscript[U, 3])(A(τ)×((x^m)/(((1+9x))^n))).

Column[
Table[
{n,(U1XoZ[0,n]//Simplify)//Expand},
{n,0,6}
]
]

Column[
Table[
{n,(U0XoZ[0,n]//Simplify)//Expand},
{n,0,6}
]
]

We need to exclude the localizing factors and examine the 3-adic valuation of what is left.

zU1XoZ[m_,n_]:=
If[
n==0,
(1+9 x) U1XoZ[m,0],
(1+9 x)^(3 n) U1XoZ[m,n]
]//Simplify//Expand

zU0XoZ[m_,n_]:=
If[
n==0,
(1+9 x) U0XoZ[m,0],
(1+9 x)^(3 n+1) U0XoZ[m,n]
]//Simplify//Expand

Below is a table of examples.  Compare with the numerators in the tables above.

(Subscript[U, 3])(((x^m)/(((1+9x))^n)))

and

(Subscript[U, 3])(A(τ)×((x^m)/(((1+9x))^n))).

Column[
Table[
{n,(zU1XoZ[0,n]//Simplify)//Expand},
{n,0,6}
]
]

Column[
Table[
{n,(zU0XoZ[0,n]//Simplify)//Expand},
{n,0,6}
]
]

Now we define a function to examine the 3-adic valuation of each coefficient.

val13[m_,n_]:=
Module[
{zpU=zU1XoZ[m,n],C={},T={}},
C=CoefficientList[zpU,x];
T=Table[IntegerExponent[C[[r+1]],3],{r,0,Length[C]-1}];
T
]

val03[m_,n_]:=
Module[
{zpU=zU0XoZ[m,n],C={},T={}},
C=CoefficientList[zpU,x];
T=Table[IntegerExponent[C[[r+1]],3],{r,0,Length[C]-1}];
T
]

Here are a couple of tests:

Column[
Table[
{n,val13[1,n]},
{n,0,6}
]
]

Column[
Table[
{n,val03[1,n]},
{n,0,5}
]
]

Our Initial Cases

At last we are in the position to check our initial relations.
We build a function which will compare the 3-adic valuation of our normalizations of

(Subscript[U, 3])(((x^m)/(((1+9x))^n)))

and

(Subscript[U, 3])(A(τ)×((x^m)/(((1+9x))^n)))

with our predicted power of 3 from our Main Lemma in the paper.

First we define (Subscript[π, 1]) and (Subscript[π, 2]), which are the 3-adic valuations which we predict:

pi1[m_,r_]:=
If[
1≤m≤3&&r≥2,
Floor[(3 r+1)/4],
If[
3 r-m+1≤0,
0,
Floor[(3 r-m+1)/4]
]
]

pi0[m_,r_]:=
If[
3 r-m-4≤0,
0,
Floor[(3 r-m-4)/4]
]

Finally, we define the difference between the 3-adic valuations that we predict, and those which we actually observe:

val1C[m_]:=
{
m,
Column[
Table[
{n,val13[m,n]-Table[pi1[m,r],{r,0,Length[val13[m,n]]-1}]},
{n,1,3}
]
]
}

val0C[m_]:=
{
m,
Column[
Table[
{n,val03[m,n]-Table[pi0[m,r],{r,0,Length[val03[m,n]]-1}]},
{n,1,3}
]
]
}

We first examine our initial relations for

(Subscript[U, 3])(((x^m)/(((1+9x))^n))),

with

1 ≤ m ≤ 3,
1 ≤ n ≤ 3.

If the difference is always nonnegative, then we have successfully verified the base case.

Column[
Table[
val1C[m],
{m,1,3}
]
]

Now we examine the initial relations we need for

(Subscript[U, 3])(A(τ)×((x^m)/(((1+9x))^n))),

with

1 ≤ m ≤ 3,
1 ≤ n ≤ 3.

Column[
Table[
val0C[m],
{m,1,3}
]
]

We have successfully established the initial cases of our induction.

Supplements to Lemmas 3.3, 3.5, 3.6

We provide some small additional computations.

In the proof of Lemma 3.6 we expand a certain polynomial of the form

-aj(x(τ))×bk(z(τ))×(1+9((x))^(3k))

We define

wjk[j_,k_]:=-av[[j+1]] bv[[k]] (1+9 x)^(3 k)

Cwjk[j_,k_]:=CoefficientList[wjk[j,k],x]

To check our 3-adic valuations, we give the following table.  We only need each value to be nonnegative.

For k=1 we have

Table[
Column[
Table[
IntegerExponent[Cwjk[j,1][[l]],3]-Floor[(3 (l-1)+j)/4],
{l,1,Length[Cwjk[j,1]]}
]
],
{j,0,2}
]

For k=2 we have

Table[
Column[
Table[
IntegerExponent[Cwjk[j,2][[l]],3]-Floor[(3 (l-1)+j)/4],
{l,1,Length[Cwjk[j,2]]}
]
],
{j,0,2}
]

For k=3 we have

Table[
Column[
Table[
IntegerExponent[Cwjk[j,3][[l]],3]-Floor[(3 (l-1)+j)/4],
{l,1,Length[Cwjk[j,3]]}
]
],
{j,0,2}
]

bj(x(τ))×(1+9((x))^(3(k-1)))

wk[k_]:=bv[[k]] (1+9 x)^(3 (k-1))

Cwk[k_]:=CoefficientList[wk[k],x]

phi[l_]:=
If[
l==0,
1,
Floor[(3 l+12)/4]
]

To check our 3-adic valuations, we give the following table.

Table[
Column[
Table[
IntegerExponent[Cwk[k][[l]],3]-phi[l-1],
{l,1,Length[Cwk[k]]}
]
],
{k,1,3}
]

We get a single negative value, corresponding to k=3, l-1=0 (the constant term).  Multiplying this out, we get

wk[3]//Expand

PolynomialMod[wk[3]//Expand,9]

This verifies that the only term failing this valuation is the constant term 1, which we use to our advantage.

wk[2]//Expand

PolynomialMod[wk[2]//Expand,9]

wk[1]//Expand

PolynomialMod[wk[1]//Expand,9]

Coefficient Congruences

We are satisfied that our 3-adic valuations are correct.  We can now compute the coefficients with these powers of 5 removed.

h1[m_,n_,r_]:=
Coefficient[zU1XoZ[m,n]//Simplify//Expand,x,r]/(3^(pi1[m,r]))

h0[m_,n_,r_]:=
Coefficient[zU0XoZ[m,n]//Simplify//Expand,x,r]/(3^(pi0[m,r]))

We want to prove the congruences of Corollary 3.7.

Column[
Table[
{Mod[h1[m,1,2],3],Mod[h0[1,3,4],3]},
{m,1,3}
]
]

Column[
Table[
{Mod[h1[m,1,4],3]},
{m,1,6}
]
]

Theta[m_]:=
If[
1≤m≤3,
0,
If[
4≤m≤6,
2,
Floor[(3 m-3)/4]-1
]
]

Now we want to prove the congruences of Corollary 3.8.

Column[
Table[
Column[
Table[
{
{m,r},
If[
pi1[m,r]+pi0[r,3]+Theta[m]-4≥0,
0,
{Mod[h1[m,1,r],3],Mod[h1[m,2,r],3],Mod[h1[m,3,r],3]}
]
},
{m,1,3 r}
]
],
{r,1,8}
]
]

Column[
Table[
Column[
Table[
{{r,w},Mod[h0[r,1,w],3],Mod[h0[r,2,w],3],Mod[h0[r,3,w],3]},
{r,1,3 w-1}
]
],
{w,1,3}
]
]

These are sufficient to justify our coefficient properties.

Computations to Repair Incongruence in Theorem 4.2.

Here we provide some important valuation computations in order to validate our principal on the stability of s(1)+s(2)+s(3).

We start with w=1.

hatT[w_]:=
Sum[
Sum[
s[m] h1[m,1,r] h0[r,3,w] 3^(pi1[m,r]+pi0[r,w]+Theta[m]-2),
{m,1,3 r}
],
{r,1,Min[3 w-1,5]}
]//Simplify//Expand

hatT[1]

hatT[2]

hatT[3]

hatT[1]+hatT[2]+hatT[3]//Expand

PolynomialMod[hatT[1]+hatT[2]+hatT[3]//Expand,9]

Cusp Analysis Computations

We will provide the means of computing the orders, and then the principal parts, of the modular functions over the cusps of (Subscript[X, 0])(6) and (Subscript[X, 0])(18).

To begin with, we will list the matrices representing the cusps of each modular curve.  The computation of these is more intricate, and we refer the reader to Chapter 3 of Diamond for the details on how such a computation is made.

The cusps of over (Subscript[X, 0])(6) may be represented with 1/6, 1/3, 1/2, 1/1; with 1/6 representing our cusp at infinity, and 1/1 representing our cusp at 0.

cusps6=
{
1/6,1/3,1/2,1/1
};

The cusps of over (Subscript[X, 0])(18) may be represented with 1/18, 1/9, 1/6, 1/3, 1/2, 2/3, 5/6, 1/1; with 1/18 representing our cusp at infinity, and 1/1 representing our cusp at 0.

cusps18=
{
1/18,1/9,1/6,1/3,1/2,2/3,5/6,1/1
};

We implement Ligozat’s formula to compute the order of an eta quotient at a cusp represented by a/c over (Subscript[X, 0])(N).  The vector s gives us the list of integer powers of η(δτ) present in our eta quotient, where δ is a divisor of N.  Here s is ordered by the size of δ.

etaCuspOrder[c_,N_,s_]:=
Sum[
(N/(24 c GCD[c,N/c])) s[[i]] ((GCD[Divisors[N][[i]],c]^2)/(Divisors[N][[i]])),
{i,1,Length[Divisors[N]]}
]

Aq=q ((QPochhammer[q^2,q^2]^2)/(QPochhammer[q,q]^7))/(((QPochhammer[q^(18),q^(18)]^2)/(QPochhammer[q^9,q^9]^7)))

Av={-7,2,0,0,7,-2};

Now we give x and z, as well as vector representations.  Here, xv is represented over the divisors of N=6, and xv1 is represented over the divisors of N=18  zv and zv1 are defined similarly.

Also, xq3=x(3τ), and z3 is defined similarly.  Finally, xv3 and zv3 are the corresponding vector representations over the divisors of N=18

xq=((q QPochhammer[(q^2),(q^2)] ((QPochhammer[(q^6),(q^6)])^5))/(((QPochhammer[q,q])^5) QPochhammer[(q^3),(q^3)]));

xq3=((q^3 QPochhammer[(q^6),(q^6)] ((QPochhammer[(q^18),(q^18)])^5))/(((QPochhammer[(q^3),(q^3)])^5) QPochhammer[(q^9),(q^9)]));

xv={-5,1,-1,5};

xv1={-5,1,-1,5,0,0};

zq=((((QPochhammer[(q^2),(q^2)])^9) ((QPochhammer[(q^3),(q^3)])^3))/(((QPochhammer[q,q])^9) ((QPochhammer[(q^6),(q^6)])^3)));

zq3=((((QPochhammer[(q^6),(q^6)])^9) ((QPochhammer[(q^9),(q^9)])^3))/(((QPochhammer[(q^3),(q^3)])^9) ((QPochhammer[(q^18),(q^18)])^3)));

zv={-9,9,3,-3};

zv1={-9,9,3,-3,0,0};

xv3={0,0,-5,1,-1,5};

zv3={0,0,-9,9,3,-3};

We compute the orders of Aq, xq1, xq3, and zq3 at the cusps for N=18.

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,Av]
},
{k,1,Length[cusps18]}
]
]

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,xv1]
},
{k,1,Length[cusps18]}
]
]

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,xv3],
etaCuspOrder[Denominator[cusps18[[k]]],18,zv3]
},
{k,1,Length[cusps18]}
]
]

We compute the orders of  ((x(τ))^l)/((x(3τ))^11) at the cusps for N=18, for l=1,2 (The case for l=0 is trivial).  This ensures that these are modular functions with a pole only at the cusp at infinity for N=6.

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,-11 xv3+xv1],
etaCuspOrder[Denominator[cusps18[[k]]],18,-11 xv3+2 xv1]
},
{k,1,Length[cusps18]}
]
]

We compute the orders of  A(τ)((x(τ))^l)z(3τ)/((x(3τ))^11) at the cusps for N=18, for l=0,1,2.  This ensures that these are modular functions with a pole only at the cusp at infinity for N=6.

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,Av-11 xv3+zv3],
etaCuspOrder[Denominator[cusps18[[k]]],18,Av-11 xv3+zv3+xv1],
etaCuspOrder[Denominator[cusps18[[k]]],18,Av-11 xv3+zv3+2 xv1]
},
{k,1,Length[cusps18]}
]
]

Now we compute the principal parts and constants of (Subscript[U, 3])(((x(τ))^l)/((x(3τ))^11)), for l=1,2, and compare to the principal parts and constants of the right-hand sides of our fundamental relations (divided by ((x(τ))^11)).

For l=1:

xS=Series[xq,{q,0,300}];

U1xS=Sum[Coefficient[xS,q,3 n] q^n,{n,0,100}];

xn11U1xleft=Series[(1/xq^(11)) U1xS,{q,0,0}]

xn11U1xright=Series[(1/xq^(11)) (19 xq+360 (xq^2)+1728 (xq^3)),{q,0,0}]

xn11U1xleft-xn11U1xright//Expand

For l=2:

x2S=Series[xq^2,{q,0,300}];

U1x2S=Sum[Coefficient[x2S,q,3 n] q^n,{n,0,100}];

xn11U1x2left=Series[(1/xq^(11)) U1x2S,{q,0,0}]

xn11U1x2right=Series[(1/xq^(11)) (10 xq+1269 (xq^2)+41904 (xq^3)+585792 (xq^4)+3732480 (xq^5)+8957952 (xq^6)),{q,0,0}]

xn11U1x2left-xn11U1x2right//Expand

Now we compute the principal parts and constants of (Subscript[U, 3])(A(τ)z(3τ)((x(τ))^l)/((x(3τ))^11)) for l=0,1,2 and compare to the principal parts and constants of the right-hand sides of our fundamental relations (multiplied by z(τ) and divided by ((x(τ))^11)).

AS=Series[Aq,{q,0,300}];

For l=0:

U01S=Sum[Coefficient[AS,q,3 n] q^n,{n,0,100}];

zxn11U01left=Series[(zq/xq^(11)) U01S,{q,0,0}]

zxn11U01right=Series[(1/xq^(11)) (33 xq+1392 (xq^2)+21120 (xq^3)+138240 (xq^4)+331776 (xq^5)),{q,0,0}]

zxn11U01left-zxn11U01right//Expand

For l=1:

AxS=Series[Aq xq,{q,0,300}];

U0xS=Sum[Coefficient[AxS,q,3 n] q^n,{n,0,100}];

zxn11U0xleft=Series[(zq/xq^(11)) U0xS,{q,0,0}]

zxn11U0xright=Series[(1/xq^(11)) (12 xq+2325 (xq^2)+121080 (xq^3)+2915136 (xq^4)+37988352 (xq^5)+277696512 (xq^6)+1074954240 (xq^7)+1719926784 (xq^8)),{q,0,0}]

zxn11U0xleft-zxn11U0xright//Expand

For l=2:

Ax2S=Series[Aq xq^2,{q,0,300}];

U0x2S=Sum[Coefficient[Ax2S,q,3 n] q^n,{n,0,100}];

zxn11U0x2left=Series[(zq/xq^(11)) U0x2S,{q,0,0}]

zxn11U0x2right=Series[(1/xq^(11)) (xq+1213 (xq^2)+176005 (xq^3)+10225152 (xq^4)+318757248 (xq^5)+6012278784 (xq^6)+72239910912 (xq^7)+558546223104 (xq^8)+2698565124096 (xq^9)+7430083706880 (xq^10)+8916100448256 (xq^11)),{q,0,0}]

zxn11U0x2left-zxn11U0x2right//Expand

Now we confirm that both 1/x(τ) and z(τ)/x(τ) have a pole only at the cusp at infinity for N=6.

Column[
Table[
{
cusps6[[k]],
etaCuspOrder[Denominator[cusps6[[k]]],6,-xv],
etaCuspOrder[Denominator[cusps6[[k]]],6,-xv+zv]
},
{k,1,Length[cusps6]}
]
]

Expanding z(τ)/x(τ)-1/x(τ) -9, we get no principal part or constant, indicating that the expression is necessarily 0.

Series[zq/xq-1/xq-9,{q,0,10}]

Finally, we show that x(τ)/((x(3τ))^3) has a pole only at infinity for N=18.

Column[
Table[
{
cusps18[[k]],
etaCuspOrder[Denominator[cusps18[[k]]],18,-3 xv3+xv1]
},
{k,1,Length[cusps18]}
]
]

Since the highest power of x(τ) in our modular equation is 3, we need only divide by  ((x(3τ))^9).  Expanding, we find that there is no principal part or constant, indicating again that the expression is 0.

Series[(1/xq3^9) (xq^3+xq^2 a2[xq3]+xq a1[xq3]+a0[xq3]),{q,0,0}]

Additional Computations, and Values for (Subscript[L, α])

To estimate the order of (Subscript[L, 1]) as defined in Line (1.2) of our main paper, we consult a result that can be found in the theory of Ramanujan--Kolberg identities (for instance, Theorem 47 from S. Radu, “An Algorithmic Approach to Ramanujan--Kolberg Identities,” Journal of Symbolic Computation, 68 (1), pp. 225-253, 2015).

We define two functions, ps and pr.

ps[y_,N_,s_]:=
(1/24) Sum[
s[[i]] ((GCD[Divisors[N][[i]],Denominator[y]]^2)/(Divisors[N][[i]])),
{i,1,Length[Divisors[N]]}
]

pr[y_,M_,r_,m_]:=
Min[
Table[
(1/24) Sum[
r[[i]] (
GCD[
Divisors[M][[i]] (Numerator[y]+GCD[m^2-1,24] l Denominator[y]),m Denominator[y]
]^2/(Divisors[M][[i]] m)
),
{i,1,Length[Divisors[M]]}
],
{l,0,m-1}
]
]

From this, we can construct a formula to estimate the lower bound of the order of a function like (Subscript[L, 1]) at the various cusps of (Subscript[X, 0])(6):

Column[
Table[
{
cusps6[[k]],
(6/(GCD[(Denominator[cusps6[[k]]])^2,6]))(pr[cusps6[[k]],2,{-7,2},3]+ps[cusps6[[k]],6,{0,0,7,-2}])
},
{k,1,Length[cusps6]}
]
]

If we again compare to the orders of z:

Column[
Table[
{
cusps6[[k]],
etaCuspOrder[Denominator[cusps6[[k]]],6,zv]
},
{k,1,Length[cusps6]}
]
]

We see that z (Subscript[L, 1]) will have a pole only at the cusp represented by 0.

As a final reference, we provide representations of (Subscript[L, 1]), (Subscript[L, 2]), (Subscript[L, 3]) in our localization ring.

L1=((33 x)/(1+9 x))+((1392 (x^2))/(1+9 x))+((21120 (x^3))/(1+9 x))+((138240 (x^4))/(1+9 x))+((331776 (x^5))/(1+9 x));

L2=((22842 x)/(((1+9 x))^3))+((20183040 (x^2))/(((1+9 x))^3))+((4342283937 (x^3))/(((1+9 x))^3))+((422213965776 (x^4))/(((1+9 x))^3))+((23457571923456 (x^5))/(((1+9 x))^3))+((836710358114304 (x^6))/(((1+9 x))^3))+((20448309908828160 (x^7))/(((1+9 x))^3))+((355390435104325632 (x^8))/(((1+9 x))^3))+((4478237668683546624 (x^9))/(((1+9 x))^3))+((41131812542547492864 (x^10))/(((1+9 x))^3))+((273107993982375297024 (x^11))/(((1+9 x))^3))+((1278439984460633997312 (x^12))/(((1+9 x))^3))+((4005979679608201543680 (x^13))/(((1+9 x))^3))+((7547714985130966646784 (x^14))/(((1+9 x))^3))+((6469469987255114268672 (x^15))/(((1+9 x))^3));

L3=((19840410 x)/(((1+9 x))^10))+((23571530159283 (x^2))/(((1+9 x))^10))+((738586235881721511 (x^3))/(((1+9 x))^10))+((4203049608924535815912 (x^4))/(((1+9 x))^10))+((8386212363570067216933728 (x^5))/(((1+9 x))^10))+((8068713484960634722222860837 (x^6))/(((1+9 x))^10))+((4489732159119205520268795934176 (x^7))/(((1+9 x))^10))+((1620165687358578886453344735595113 (x^8))/(((1+9 x))^10))+((409640473960472924691754356501662934 (x^9))/(((1+9 x))^10))+((76665846599126213549392262308624186257 (x^10))/(((1+9 x))^10))+((11060386180765899499576275417439093222848 (x^11))/(((1+9 x))^10))+((1268588359944072109817116244305617465985536 (x^12))/(((1+9 x))^10))+((118500845627334595003829983782536778012340224 (x^13))/(((1+9 x))^10))+((9189819770416299226478483417921881569463959552 (x^14))/(((1+9 x))^10))+((600926837173520408339999953468031596655431778304 (x^15))/(((1+9 x))^10))+((33557921615060149303813266299361002580886897557504 (x^16))/(((1+9 x))^10))+((1617370874980125718627550807577373632654965477474304 (x^17))/(((1+9 x))^10))+((67872513679702503457384546607807276086380278990241792 (x^18))/(((1+9 x))^10))+((2498426872980248557249636784425796873719124812823003136 (x^19))/(((1+9 x))^10))+((81179142516677319183192013913721630858912066015810551808 (x^20))/(((1+9 x))^10))+((2340585944558764986397921313267162997323836407633558896640 (x^21))/(((1+9 x))^10))+((60151745834472682715607732712296522502996383439311303868416 (x^22))/(((1+9 x))^10))+((1383088048478729382683269748574224882954353766652226534637568 (x^23))/(((1+9 x))^10))+((28542720597261425322598640964049097516266278156861569671102464 (x^24))/(((1+9 x))^10))+((530044278281848085102348569348534858508044906861231759001911296 (x^25))/(((1+9 x))^10))+((8875884380278730034670668807638887400013927783247089702392561664 (x^26))/(((1+9 x))^10))+((134247620162343493148623299410796787580822222652220344875907809280 (x^27))/(((1+9 x))^10))+((1836214606946416916927518861308772270310172856088641112299932745728 (x^28))/(((1+9 x))^10))+((22730565357787935150266244247513099383947513644267556573313308295168 (x^29))/(((1+9 x))^10))+((254765603268228402399005765047954288621836134439140802037152894418944 (x^30))/(((1+9 x))^10))+((2585323015404275113501335617286684850407918102126401409752513208385536 (x^31))/(((1+9 x))^10))+((23744014430082414520994856398217822478002804042635928726465253031804928 (x^32))/(((1+9 x))^10))+((197194458558152677820733110868864947006875910349736323682066549897691136 (x^33))/(((1+9 x))^10))+((1479018060262782064669442532031390126308301027502995422981954105218433024 (x^34))/(((1+9 x))^10))+((10000223067044643673703678905676443496804366467193188401148942276953636864 (x^35))/(((1+9 x))^10))+((60810514582545270556852552369799414589488735106493949076047322856613216256 (x^36))/(((1+9 x))^10))+((331570872815540577929165590720012062779488659531390521502861381497260081152 (x^37))/(((1+9 x))^10))+((1614995079358995271646599486180718884379164924863571993705989165518193426432 (x^38))/(((1+9 x))^10))+((6994212016946235944386490781442642058599653651174173599816924461406447730688 (x^39))/(((1+9 x))^10))+((26777630060311148221512625462537307058538347773987679706821582698893667205120 (x^40))/(((1+9 x))^10))+((89982044858382248551500544132258674891592499020232116279202471727245027180544 (x^41))/(((1+9 x))^10))+((263018178027390101359273744631940247863142873021768949560057076424689533845504 (x^42))/(((1+9 x))^10))+((661152441789538421949575629242228663328852415608789545222070270784289374208000 (x^43))/(((1+9 x))^10))+((1408234446357568135090316255134355665788334327084748994487665673613340573696000 (x^44))/(((1+9 x))^10))+((2491954298483989296156432453113596902075949333953164714900538287801762630860800 (x^45))/(((1+9 x))^10))+((3564768233868033019592767589746075128065199355850617961213535636291226913734656 (x^46))/(((1+9 x))^10))+((3960681648529076801419084173524845154638263346245590589590883367685558246572032 (x^47))/(((1+9 x))^10))+((3206711775665210031024093179024456215871878712332285638381245539860844677955584 (x^48))/(((1+9 x))^10))+((1682926899635711964172694062937152579793802351509375713443259135683793174659072 (x^49))/(((1+9 x))^10))+((429683463736777522767496356494592148032460174853457628964236375068202512678912 (x^50))/(((1+9 x))^10));